Subject: Re: Text on curved surface-r13
From: phil@prallen.demon.co.uk (phil)
Date: Thu, 05 Dec 1996 00:03:07 GMT
On 3 Dec 1996 00:38:35 -0800, TC wrote:
Hi
>Can AutoCad r13 get text to 'lay' on curved surface while conforming to
>the curved plane? Is there a lisp routine for this?
Ther is a lisp routine for this, its on the R12 bonus CD, its called
ATEXT.LSP
if you havn't got it here it is
==========start===============
;atext.lsp
;
; Copyright (C) 1988-1992 by Autodesk, Inc.
;
; Permission to use, copy, modify, and distribute this software
; for any purpose and without fee is hereby granted, provided
; that the above copyright notice appears in all copies and that
; both that copyright notice and this permission notice appear in
; all supporting documentation.
;
; THIS SOFTWARE IS PROVIDED "AS IS" WITHOUT EXPRESS OR IMPLIED
; WARRANTY. ALL IMPLIED WARRANTIES OF FITNESS FOR ANY PARTICULAR
; PURPOSE AND OF MERCHANTABILITY ARE HEREBY DISCLAIMED.
; ****************************************************************
; Larry Knott
;
; Draws center aligned text along an ARC. The start point of the
text
; is the ENDpoint of the ARC closest the pick point.
;
(defun rtd (a) (* a (/ 180 pi))) ; radians to degrees
(defun getarc (/ no_arc e0 e1)
(setq no_arc T)
(while no_arc
(if (setq e0 (entsel "\nSelect arc: "))
(if (= (cdr (assoc 0 (setq e1 (entget (car e0))))) "ARC")
(setq no_arc nil)
(princ (strcat (cdr (assoc 0 e1)) ", Not an arc."))
) ; end IF
(princ " No object found.")
) ; end IF
) ; end WHILE
(setq c1 (cdr (assoc 10 e1)) ; center point
r1 (cdr (assoc 40 e1)) ; radius
a0 (cdr (assoc 50 e1)) ; start arc angle
a1 (cdr (assoc 51 e1)) ; end arc angle
i1 (if (> a1 a0) ; included angle
(- a1 a0)
(+ a1 (- (* pi 2) a0))
) ; end IF
p1 (osnap (cadr e0) "end") ; start point pick
p2 (polar c1 a1 r1) ; end point arc
) ; end SETQ
) ; end DEFUN
(defun getset (/ h1 t1 n1 a2)
(setq h1 ; check current text style
height
(if (zerop (cdr (assoc 40 (tblsearch "style" (getvar
"textstyle")))))
(getdist p1 "\nHeight: ") ; text height
nil ; height defined by STYLE
) ; end IF
t1 (getstring T "\nText: ") ; text string
n1 1 ; counter
a2 (/ i1 (1- (strlen t1))) ; angle increment
) ; end SETQ
(if (< (distance p1 p2) 1.0E-8) ; clockwise?
(setq o1 '-) ; clockwise
(setq o1 '+ ; counter-clockwise
a1 a0
) ; end SETQ
) ; end IF
(setvar "cmdecho" 0) ; suppress command echo
(setvar "highlight" 0) ; suppress hightlighting
(setvar "blipmode" 0) ; suppress blips
(repeat (strlen t1) ; for each character
(command "text" "c" p1) ; TEXT command
(if h1 (command h1))
(command ((eval o1) (rtd a1) 90) (substr t1 n1 1))
(setq a1 ((eval o1) a1 a2) ; increment angle
n1 (1+ n1) ; increment counter
p1 (polar c1 a1 r1) ; increment text point
) ; end SETQ
) ; end REPEAT
(setvar "cmdecho" 1) ; enable command echo
(setvar "highlight" 1) ; enable hightlighting
(setvar "blipmode" 1) ; enable blips
) ; end DEFUN
(defun c:atext()
(princ "\n *** Draws text on arcs ***") ; banner
(getarc) ; get the arc
(getset) ; get the settings and draw
text
(prin1) ; quiet exit
) ; end DEFUN
===============end====================
its not bad, the only fault is that if you select a large text height
and a small arc the letters in the text overlap each other. It takes
me a few goes to get it right.
hope it helps
Phil
------------------------------------
*********pallen@bayside.net*********
*********crook@trust-me.com*********
*****phil.allen@thepentagon.com*****
******phil@prallen.demon.co.uk******
***http://www.prallen.demon.co.uk***
------------------------------------
Subject: Re: Can AutoLISP do this
From: duhvinci@rockford.com (Patrick Hughes)
Date: Thu, 05 Dec 1996 00:10:11 GMT
With adroit appendages floating frantically athwart the
electromechanical ciphering device endeavored to convey the supervening erudition to the
espying public:
>From the first chapter I understand about 5 words but I like baroque
>languages.
>In unix it's of course no problem at all.
>For setting the DOS Master environment there are a few tricks:
>1) XSET a dos utility may set the master environment. (simtel ?)
>2) 4DOS for DOS or its counterpart 4NT for Win95/NT allows to set it
>too.
>How to do it in C is beyond my knowledge (as with understanding the
>first chapter, is it pornographic?).
>BTW: I had to change my From: header, because of overboarding junk mail.
>Are three times a week the same rate as yours?
>---
>Reini Urban, TU Graz, Architecture & X-RAY
> http://xarch.tu-graz.ac.at/autocad/
Three times is about normal, I'm rather new to all of this so
receiving e-mail is still . I just trash it as soon as it comes
in anyway. Besides you never know when that perfect get-rich-quick
scheme is going to arrive .
--
Patrick Hughes
Engineered Design Solutions
e-mail duhvinci@rockford.com
homepage http://www.rockford.com/duhvinci
--------------------------------------------------
* Machine design, detail & build
* Cam design & manufacturing
* Machine animation
--------------------------------------------------
